易语言编写QQ游戏找茬系列辅助工具 大家来找茬源码

易语言写一些小软件还是挺方便的,但是写waigua貌似是违法的,所以大家不要去碰,这里提供的QQ游戏大家来找茬易语言源码和美女来找茬源码,仅供学习,请勿用于其它用途。

闪动的地方就是两张图不同的地方,直接点击就行了,效果很好。
.版本 2
.支持库 shellEx
.支持库 shell
.支持库 eAPI

.程序集 窗口程序集_启动窗口
.程序集变量 F3
.程序集变量 F4
.程序集变量 上
.程序集变量 下
.程序集变量 左
.程序集变量 右

.子程序 __启动窗口_创建完毕
.局部变量 zc热键, 整数型
.局部变量 横坐标, 文本型
.局部变量 纵坐标, 文本型
.局部变量 循环变量, 整数型

F3 = zc热键 (取窗口句柄 (), 热键说明.取窗口句柄 (), 0, #F3键)
F4 = zc热键 (取窗口句柄 (), 热键说明.取窗口句柄 (), 0, #F4键)
上 = zc热键 (取窗口句柄 (), 热键说明.取窗口句柄 (), 0, #上光标键)
下 = zc热键 (取窗口句柄 (), 热键说明.取窗口句柄 (), 0, #下光标键)
左 = zc热键 (取窗口句柄 (), 热键说明.取窗口句柄 (), 0, #左光标键)
右 = zc热键 (取窗口句柄 (), 热键说明.取窗口句柄 (), 0, #右光标键)
添加提示 (还原位置.取窗口句柄 (), “恢复到记录的位置”, 假, 假)
载入 (闪图窗口, _启动窗口, 假)
窗口透明化 (闪图窗口.取窗口句柄 (), 225, , 真)
.如果 (读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “初次使用”, “是”) ≠ “否”)
    写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “初次使用”, “否”)
.否则
    .如果真 (读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “找茬类型”, ) = “大家来找茬”)
        大家来找茬.选中 = 真
    .如果真结束
    .如果真 (读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “找茬类型”, ) = “美女找茬”)
        美女找茬.选中 = 真
    .如果真结束
    .计次循环首 (10, 循环变量)
        .如果真 (读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “找茬频率”, “100”) = 闪图频率.取项目文本 (循环变量 - 1))
            闪图频率.现行选中项 = 循环变量 - 1
            跳出循环 ()
        .如果真结束

    .计次循环尾 ()
    .如果真 (读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “左边”, “无”) ≠ “无” 或 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “顶边边”, “无”) ≠ “无” 且 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “左边”, “无”) ≠ “无” 或 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “顶边”, “无”) ≠ “无”)
        跟随.选中 = 假
        闪图窗口.承载板.可视 = 假
        .如果真 (大家来找茬.选中 = 真)
            横坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “左边”, “无”)
            纵坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “顶边”, “无”)
            .如果真 (横坐标 ≠ “无”)
                记录1.内容 = 横坐标
                闪图窗口.左边 = 到整数 (记录1.内容)
            .如果真结束
            .如果真 (纵坐标 ≠ “无”)
                记录2.内容 = 纵坐标
                闪图窗口.顶边 = 到整数 (记录2.内容)
            .如果真结束
            闪图窗口.宽度 = 381
            闪图窗口.高度 = 287
            闪图窗口.画板.左边 = -550
            闪图窗口.画板.顶边 = -312
        .如果真结束
        .如果真 (美女找茬.选中 = 真)
            横坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “左边”, “无”)
            纵坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “顶边”, “无”)
            .如果真 (横坐标 ≠ “无”)
                记录1.内容 = 横坐标
                闪图窗口.左边 = 到整数 (记录1.内容)
            .如果真结束
            .如果真 (纵坐标 ≠ “无”)
                记录2.内容 = 纵坐标
                闪图窗口.顶边 = 到整数 (记录2.内容)
            .如果真结束
            闪图窗口.宽度 = 498
            闪图窗口.高度 = 448
            闪图窗口.画板.左边 = -517
            闪图窗口.画板.顶边 = -215
        .如果真结束

    .如果真结束

.如果结束


.子程序 _取图_被单击

闪图窗口.可视 = 真
窗口句柄 = 取句柄2 (“ZhaoCha.exe”, , “大家来找茬”)
.如果真 (大家来找茬.选中 = 真)
    闪图窗口.画板.底图 = 快照 (窗口句柄, 1024, 768)
.如果真结束
.如果真 (美女找茬.选中 = 真)
    闪图窗口.画板.底图 = 快照 (窗口句柄, 1024, 738)
.如果真结束


.子程序 __启动窗口_位置被改变

.如果真 (跟随.选中 = 真)
    闪图窗口.左边 = _启动窗口.左边
    闪图窗口.顶边 = _启动窗口.顶边 + _启动窗口.高度 + 1
.如果真结束


.子程序 __启动窗口_可否被关闭, 逻辑型

闪图窗口.销毁 ()
返回 (真)


.子程序 _置顶_被单击

.如果 (置顶.选中 = 真)
    _启动窗口.总在最前 = 真
.否则
    _启动窗口.总在最前 = 假
.如果结束


.子程序 _计时器_周期事件

闪图窗口.承载板.可视 = 假
.如果真 (大家来找茬.选中 = 真)
    闪图窗口.画板.底图 = 快照 (窗口句柄, 1024, 768)
.如果真结束
.如果真 (美女找茬.选中 = 真)
    闪图窗口.画板.底图 = 快照 (窗口句柄, 1024, 738)
.如果真结束
.如果 (闪图窗口.可视 = 真)
    闪图窗口.可视 = 假
.否则
    闪图窗口.可视 = 真
.如果结束


.子程序 _左调_被单击

跟随.选中 = 假
闪图窗口.左边 = 闪图窗口.左边 - 1

.子程序 _上调_被单击

跟随.选中 = 假
闪图窗口.顶边 = 闪图窗口.顶边 - 1

.子程序 _右调_被单击

跟随.选中 = 假
闪图窗口.左边 = 闪图窗口.左边 + 1

.子程序 _下调_被单击

跟随.选中 = 假
闪图窗口.顶边 = 闪图窗口.顶边 + 1


.子程序 _还原位置_被单击
.局部变量 横坐标, 文本型
.局部变量 纵坐标, 文本型




.子程序 _记录_被单击

跟随.选中 = 假
记录1.内容 = 到文本 (闪图窗口.左边)
记录2.内容 = 到文本 (闪图窗口.顶边)
写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “初次使用”, “否”)
.如果真 (大家来找茬.选中 = 真)
    写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “左边”, 记录1.内容)
    写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “顶边”, 记录2.内容)
.如果真结束
.如果真 (美女找茬.选中 = 真)
    写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “左边”, 记录1.内容)
    写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “顶边”, 记录2.内容)
.如果真结束


.子程序 _闪图_被单击

_取图_被单击 ()
.如果 (闪图.标题 = “闪图”)
    计时器.时钟周期 = 到整数 (闪图频率.内容)
    闪图.标题 = “停止”
.否则
    计时器.时钟周期 = 0
    闪图窗口.可视 = 假
    闪图.标题 = “闪图”
.如果结束


.子程序 _热键说明_反馈事件, 整数型
.参数 参数一, 整数型
.参数 参数二, 整数型

.如果真 (参数一 = F3)
    _闪图_被单击 ()
.如果真结束
.如果真 (参数一 = F4)
    _还原位置_被单击 ()
.如果真结束
.如果真 (参数一 = 上)
    _上调_被单击 ()
.如果真结束
.如果真 (参数一 = 下)
    _下调_被单击 ()
.如果真结束
.如果真 (参数一 = 左)
    _左调_被单击 ()
.如果真结束
.如果真 (参数一 = 右)
    _右调_被单击 ()
.如果真结束


.子程序 _还原位置_鼠标位置被移动, 逻辑型, , 窗口置顶会使组件的提示框无法显示,此子程序用以解决该问题。
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.局部变量 是否移入, 逻辑型, 静态

.如果 (横向位置 ≥ 0 且 横向位置 ≤ 20 且 纵向位置 ≥ 0 且 纵向位置 ≤ 20)
    .如果真 (是否移入 = 假)
        捕获鼠标 (还原位置.取窗口句柄 ())
        _启动窗口.总在最前 = 假
        是否移入 = 真
    .如果真结束

.否则
    .如果真 (是否移入 = 真)
        释放鼠标 ()
        .如果真 (置顶.选中 = 真)
            _启动窗口.总在最前 = 真
        .如果真结束
        是否移入 = 假
    .如果真结束

.如果结束


.子程序 _跟随_被单击

.如果真 (跟随.选中 = 真)
    闪图窗口.可视 = 真
    闪图窗口.左边 = _启动窗口.左边
    闪图窗口.顶边 = _启动窗口.顶边 + _启动窗口.高度 + 1
.如果真结束


.子程序 _大家来找茬_被单击
.局部变量 横坐标, 文本型
.局部变量 纵坐标, 文本型

闪图窗口.宽度 = 381
闪图窗口.高度 = 287
闪图窗口.画板.左边 = -550
闪图窗口.画板.顶边 = -312
闪图窗口.承载板.宽度 = 381
闪图窗口.承载板.高度 = 296
写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “找茬类型”, “大家来找茬”)
横坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “左边”, “无”)
纵坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “大家来找茬”, “顶边”, “无”)
.如果真 (横坐标 ≠ “无”)
    记录1.内容 = 横坐标
    闪图窗口.左边 = 到整数 (记录1.内容)
.如果真结束
.如果真 (纵坐标 ≠ “无”)
    记录2.内容 = 纵坐标
    闪图窗口.顶边 = 到整数 (记录2.内容)
.如果真结束
.如果真 (横坐标 = “无” 或 纵坐标 = “无”)
    记录1.内容 = “”
    记录2.内容 = “”
    .如果真 (跟随.选中 = 假)
        跟随.选中 = 真
        _跟随_被单击 ()
    .如果真结束

.如果真结束


.子程序 _美女找茬_被单击
.局部变量 横坐标, 文本型
.局部变量 纵坐标, 文本型

闪图窗口.宽度 = 498
闪图窗口.高度 = 448
闪图窗口.画板.左边 = -517
闪图窗口.画板.顶边 = -215
闪图窗口.承载板.宽度 = 498
闪图窗口.承载板.高度 = 457
写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “找茬类型”, “美女找茬”)
横坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “左边”, “无”)
纵坐标 = 读配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “美女找茬”, “顶边”, “无”)
.如果真 (横坐标 ≠ “无”)
    记录1.内容 = 横坐标
    闪图窗口.左边 = 到整数 (记录1.内容)
.如果真结束
.如果真 (纵坐标 ≠ “无”)
    记录2.内容 = 纵坐标
    闪图窗口.顶边 = 到整数 (记录2.内容)
.如果真结束
.如果真 (横坐标 = “无” 或 纵坐标 = “无”)
    记录1.内容 = “”
    记录2.内容 = “”
    .如果真 (跟随.选中 = 假)
        跟随.选中 = 真
        _跟随_被单击 ()
    .如果真结束

.如果真结束


.子程序 _记录1_内容被改变

跟随.选中 = 假
闪图窗口.左边 = 到数值 (记录1.内容)


.子程序 _记录2_内容被改变

跟随.选中 = 假
闪图窗口.顶边 = 到数值 (记录2.内容)


.子程序 _闪图频率_列表项被选择

.如果真 (计时器.时钟周期 ≠ 0)
    计时器.时钟周期 = 到数值 (闪图频率.内容)
.如果真结束
写配置项 (取特定目录 (#程序数据目录) + “找茬配置.ini”, “找茬”, “找茬频率”, 闪图频率.内容)

需要成品 可以留言。

未经允许不得转载:军哥驿站 » 易语言编写QQ游戏找茬系列辅助工具 大家来找茬源码

赞 (0) 打赏

觉得文章有用就打赏一下文章作者

支付宝扫一扫打赏

微信扫一扫打赏